Oracle developer以其快速的數據處理開發而聞名，其異常處理機制也是比較完善，不可小覷。

1、 異常的優點

如果沒有異常，在程序中，應當檢查每個命令的成功還是失敗，如

BEGIN

SELECT ...

-- check for ’no data found’ error

SELECT ...

-- check for ’no data found’ error

SELECT ...

-- check for ’no data found’ error

這種實現的方法缺點在于錯誤處理沒有與正常處理分開，可讀性差，使用異常，可以方便處理錯誤，而且異常處理程序與正常的事務邏輯分開，提高了可讀性，如

BEGIN

SELECT ...

SELECT ...

SELECT ...

...

EXCEPTION

WHEN NO_DATA_FOUND THEN -- catches all ’no data found’ errors

2、 異常的分類

有兩種類型的異常，一種為內部異常，一種為用戶自定義異常，內部異常是執行期間返回到PL/SQL塊的ORACLE錯誤或由PL/SQL代碼的某操作引起的錯誤，如除數為零或內存溢出的情況。用戶自定義異常由開發者顯示定義，在PL/SQL塊中傳遞信息以控制對于應用的錯誤處理。

每當PL/SQL違背了ORACLE原則或超越了系統依賴的原則就會隱式的產生內部異常。因為每個ORACLE錯誤都有一個號碼并且在PL/SQL中異常通過名字處理，ORACLE提供了預定義的內部異常。如SELECT INTO 語句不返回行時產生的ORACLE異常NO_DATA_FOUND。對于預定義異常，現將最常用的異常列舉如下：

exception oracle error sqlcode value condition

no_data_found ora-01403 +100 select into 語句沒有符合條件的記錄返回

too_mang_rows ora-01422 -1422 select into 語句符合條件的記錄有多條返回

dup_val_on_index ora-00001 -1 對于數據庫表中的某一列，該列已經被限制為唯一索引，程序試圖存儲兩個重復的值

value_error ora-06502 -6502 在轉換字符類型，截取或長度受限時，會發生該異常，如一個字符分配給一個變量，而該變量聲明的長度比該字符短，就會引發該異常

storage_error ora-06500 -6500 內存溢出

zero_divide ora-01476 -1476 除數為零

case_not_found ora-06592 -6530 對于選擇case語句，沒有與之相匹配的條件，同時，也沒有else語句捕獲其他的條件

cursor_already_open ora-06511 -6511 程序試圖打開一個已經打開的游標

timeout_on_resource ora-00051 -51 系統在等待某一資源，時間超時

如果要處理未命名的內部異常，必須使用OTHERS異常處理器或PRAGMA EXCEPTION_INIT 。PRAGMA由編譯器控制，或者是對于編譯器的注釋。PRAGMA在編譯時處理，而不是在運行時處理。EXCEPTION_INIT告訴編譯器將異常名與ORACLE錯誤碼結合起來，這樣可以通過名字引用任意的內部異常，并且可以通過名字為異常編寫一適當的異常處理器。

在子程序中使用EXCEPTION_INIT的語法如下：

PRAGMA EXCEPTION_INIT(exception_name, -Oracle_error_number);

在該語法中，異常名是聲明的異常，下例是其用法：

DECLARE

deadlock_detected EXCEPTION;

PRAGMA EXCEPTION_INIT(deadlock_detected, -60);

BEGIN

... -- Some operation that causes an ORA-00060 error

EXCEPTION

WHEN deadlock_detected THEN

-- handle the error

END;

對于用戶自定義異常，只能在PL/SQL塊中的聲明部分聲明異常，異常的名字由EXCEPTION關鍵字引入：

reserved_loaned Exception

產生異常后，控制傳給了子程序的異常部分，將異常轉向各自異常控制塊，必須在代碼中使用如下的結構處理錯誤：

Exception

When exception1 then

Sequence of statements;

When exception2 then

Sequence of statements;

When others then

3、異常的拋出

由三種方式拋出異常

◆1． 通過PL/SQL運行時引擎

◆2. 使用RAISE語句

◆3. 調用RAISE_APPLICATION_ERROR存儲過程

當數據庫或PL/SQL在運行時發生錯誤時，一個異常被PL/SQL運行時引擎自動拋出。異常也可以通過RAISE語句拋出

RAISE exception_name;

顯式拋出異常是程序員處理聲明的異常的習慣用法，但RAISE不限于聲明了的異常，它可以拋出任何任何異常。例如，你希望用TIMEOUT_ON_RESOURCE錯誤檢測新的運行時異常處理器，你只需簡單的在程序中使用下面的語句：

RAISE TIMEOUT_ON_RESOUCE;

比如下面一個訂單輸入的例子，若當訂單小于庫存數量，則拋出異常，并且捕獲該異常，處理異常

DECLARE

inventory_too_low EXCEPTION;

---其他聲明語句

BEGIN

IF order_rec.qty>inventory_rec.qty THEN

RAISE inventory_too_low;

END IF

EXCEPTION

WHEN inventory_too_low THEN

order_rec.staus:='backordered';

END;

RAISE_APPLICATION_ERROR內建函數用于拋出一個異常并給異常賦予一個錯誤號以及錯誤信息。自定義異常的缺省錯誤號是+1,缺省信息是User_Defined_Exception。RAISE_APPLICATION_ERROR函數能夠在pl/sql程序塊的執行部分和異常部分調用，顯式拋出帶特殊錯誤號的命名異常。 Raise_application_error(error_number,message[,true,false]))

錯誤號的范圍是-20,000到-20,999。錯誤信息是文本字符串，最多為2048字節。TRUE和FALSE表示是添加(TRUE)進錯誤堆(ERROR STACK)還是覆蓋(overwrite)錯誤堆(FALSE)。缺省情況下是FALSE。

如下代碼所示：

IF product_not_found THEN

RAISE_APPLICATION_ERROR(-20123,'Invald product code' TRUE);

END IF;

4、異常的處理

PL/SQL程序塊的異常部分包含了程序處理錯誤的代碼，當異常被拋出時，一個異常陷阱就自動發生，程序控制離開執行部分轉入異常部分,一旦程序進入異常部分就不能再回到同一塊的執行部分。下面是異常部分的一般語法：

EXCEPTION

WHEN exception_name THEN

Code for handing exception_name

[WHEN another_exception THEN

Code for handing another_exception]

[WHEN others THEN

code for handing any other exception.]

用戶必須在獨立的WHEN子串中為每個異常設計異常處理代碼，WHEN OTHERS子串必須放置在最后面作為缺省處理器處理沒有顯式處理的異常。當異常發生時，控制轉到異常部分，ORACLE查找當前異常相應的WHEN..THEN語句，捕捉異常，THEN之后的代碼被執行，如果錯誤陷阱代碼只是退出相應的嵌套塊，那么程序將繼續執行內部塊END后面的語句。如果沒有找到相應的異常陷阱，那么將執行WHEN OTHERS。在異常部分WHEN 子串沒有數量限制。

EXCEPTION

WHEN inventory_too_low THEN

order_rec.staus:='backordered';

replenish_inventory(inventory_nbr=>

inventory_rec.sku,min_amount=>order_rec.qty-inventory_rec.qty);

WHEN discontinued_item THEN

--code for discontinued_item processing

WHEN zero_divide THEN

--code for zero_divide

WHEN OTHERS THEN

--code for any other exception

END;

當異常拋出后，控制無條件轉到異常部分，這就意味著控制不能回到異常發生的位置，當異常被處理和解決后，控制返回到上一層執行部分的下一條語句。

BEGIN

DECLARE

bad_credit exception;

BEGIN

RAISE bad_credit;

--發生異常，控制轉向；

EXCEPTION

WHEN bad_credit THEN

dbms_output.put_line('bad_credit');

END;

--bad_credit異常處理后，控制轉到這里

EXCEPTION

WHEN OTHERS THEN

--控制不會從bad_credit異常轉到這里

--因為bad_credit已被處理

END;

當異常發生時，在塊的內部沒有該異常處理器時，控制將轉到或傳播到上一層塊的異常處理部分。

BEGIN

DECLARE ---內部塊開始

bad_credit exception;

BEGIN

RAISE bad_credit;

--發生異常，控制轉向；

EXCEPTION

WHEN ZERO_DIVIDE THEN --不能處理bad_credite異常

dbms_output.put_line('divide by zero error');

END --結束內部塊

--控制不能到達這里，因為異常沒有解決；

--異常部分

EXCEPTION

WHEN OTHERS THEN

--由于bad_credit沒有解決，控制將轉到這里

END;

5、異常的傳播

沒有處理的異常將沿檢測異常調用程序傳播到外面，當異常被處理并解決或到達程序最外層傳播停止。在聲明部分拋出的異常將控制轉到上一層的異常部分。

BEGIN

executable statements

BEGIN

today DATE:='SYADATE'; --ERRROR

BEGIN --內部塊開始

dbms_output.put_line('this line will not execute');

EXCEPTION

WHEN OTHERS THEN

--異常不會在這里處理

END;--內部塊結束

EXCEPTION

WHEN OTHERS THEN

處理異常

END

執行部分拋出的異常將首先傳遞到同一塊的異常部分，如果在同一塊的異常部分沒有處理這個異常的處理器，那么異常將會傳播到上一層的異常部分中，一直到最外層。

在異常部分拋出的異常將控制轉到上一層的異常部分。

另外錯誤報告函數SQLCODE和SQLERRM在OTHERS處理器中特別有用，因為它們返回ORACLE錯誤代碼和消息。如下例所示：

declare

err_num NUMBER;

err_msg VARCHAR2(100);

BEGIN

...

EXCEPTION

WHEN OTHERS THEN

err_num := SQLCODE;

err_msg := SUBSTR(SQLERRM, 1, 100);

INSERT INTO errors VALUES (err_num, err_msg);

END;

2007-5-7 19:09:02 查看評語»»»

2007-5-7 19:09:43 oracle 異常處理

~~~~有關于異常處理的3個知識點！

1.EXCEPTION_INT編譯指示

功能是將某命名異常同某特定Oracle錯誤關聯起來.

主用用來捕捉某特定異常錯誤,而不是通過OTHERS來處理.

語法:PROGMA EXCEPTION_INIT(exception_name,oracle_error_number)

SQL>

SQL> DECLARE

2 expa EXCEPTION;

3 PRAGMA EXCEPTION_INIT(expa,-6502);

4 vn NUMBER(1);

5 BEGIN

6 vn:=24;

7 EXCEPTION

8 WHEN expa THEN

9 dbms_output.put_line('數字或值錯誤 : 數值精度太高');

10 WHEN OTHERS THEN

11 dbms_output.put_line(SQLCODE);

12 dbms_output.put_line(substr(SQLERRM,1,100));

13 END;

14 /

數字或值錯誤 : 數值精度太高

PL/SQL procedure successfully completed

SQL>

2.RAISE_APPLICATION_ERROR

功能用來自定義錯誤消息

語法: RAISE_APPLICATION_ERROR(error_number,error_message,[keep_errors])

error_number:-20 000到-20 999之間的值

error_message:必須少于512個字符

keep_errors:布爾值.為真則新的錯誤將被加到已存在的錯誤清單中（如果已存在的話），為假（默認值）則新的錯誤將代替當前的錯誤清單.

SQL> BEGIN

2 UPDATE t SET a='TEST' WHERE a='12345';

3 IF SQL%NOTFOUND THEN

4 raise_application_error(-20001,'你傻了？知道沒有這樣的數據還去更新！');

5 END IF;

6 EXCEPTION

7 WHEN OTHERS THEN

8 dbms_output.put_line(substr(SQLERRM,1,100));

9 END;

10 /

ORA-20001: 你傻了？知道沒有這樣的數據還去更新！

PL/SQL procedure successfully completed

SQL>

3.異常傳播

A可執行部分發生的異常

1)如果當前語句塊有該異常的處理程序則執行之，控制權交由外層語句塊.

當前語句塊有該異常的處理程序:

SQL> DECLARE

2 expa EXCEPTION;

3 expb EXCEPTION;

4 BEGIN

5 BEGIN

6 RAISE expa;

7 EXCEPTION

8 WHEN expa THEN

9 dbms_output.put_line('異常A產生');

10 END;

11 EXCEPTION

12 WHEN expb THEN

13 dbms_output.put_line('異常B產生');

14 END;

15 /

異常A產生

PL/SQL procedure successfully completed

SQL>

2)如果當前語句沒有該異常的處理程序則通過外層語句塊中產生該異常來傳播該異常，然后通過外層異常處理程序按步驟１來處理.若外層沒有該異常的處理程序則異常傳播到調用環境.

當前語句塊沒有該異常的處理程序,外層語句塊中產生該異常并處理

SQL> DECLARE

2 expa EXCEPTION;

3 expb EXCEPTION;

4 BEGIN

5 BEGIN

6 RAISE expb;

7 EXCEPTION

8 WHEN expa THEN

9 dbms_output.put_line('異常A產生');

10 END;

11 EXCEPTION

12 WHEN expb THEN

13 dbms_output.put_line('異常B產生');

14 END;

15 /

異常B產生

PL/SQL procedure successfully completed

SQL>

當前語句塊沒有該異常的處理程序,外層語句塊中產生該異常且沒有該異常處理程序，異常傳播到調用環境

SQL> DECLARE

2 expa EXCEPTION;

3 expb EXCEPTION;

4 BEGIN

5 BEGIN

6 RAISE expb;

7 EXCEPTION

8 WHEN expa THEN

9 dbms_output.put_line('異常A產生');

10 END;

11 EXCEPTION

12 WHEN expa THEN

13 dbms_output.put_line('異常A產生');

14 END;

15 /

DECLARE

expa EXCEPTION;

expb EXCEPTION;

BEGIN

BEGIN

RAISE expb;

EXCEPTION

WHEN expa THEN

dbms_output.put_line('異常A產生');

END;

EXCEPTION

WHEN expa THEN

dbms_output.put_line('異常A產生');

END;

ORA-06510: PL/SQL: 無法處理的用戶自定義異常事件

ORA-06512: 在line 6

SQL>

B聲明部分發生的異常

聲明部分某賦值發生異常，該異常被立即傳播到外層語句塊，之后按＂A可執行部分發生的異常＂規則來處理

SQL> BEGIN

2 DECLARE

3 vn NUMBER(1):=25;

4 BEGIN

5 NULL;

6 EXCEPTION

7 WHEN OTHERS THEN

8 dbms_output.put_line('異常在內層被處理！');

9 END;

10 EXCEPTION

11 WHEN OTHERS THEN

12 dbms_output.put_line('異常在外層被處理！');

13 END;

14 /

異常在外層被處理！

PL/SQL procedure successfully completed

SQL>

C異常部分發生的異常

異常處理器中也會產生異常，如RAISE或運行錯誤產生，這里異常立即被傳播到外層同＂B聲明部分發生的異常＂

例子1

SQL>

SQL> BEGIN

2 DECLARE

3 expa EXCEPTION;

4 expb EXCEPTION;

5 BEGIN

6 RAISE expa;

7 EXCEPTION

8 WHEN expa THEN

9 RAISE expb;

10 WHEN expb THEN

11 --這里雖然有expb異常處理語句，但是該異常會立即傳播到外層

12 dbms_output.put_line('內層捕捉到異常B');

13 END;

14 EXCEPTION

15 WHEN OTHERS THEN

16 dbms_output.put_line('外層捕捉到異常B');

17 END;

18 /

外層捕捉到異常B

PL/SQL procedure successfully completed

SQL>

例子2

SQL> desc t;

Name Type

---- ---------

ID NUMBER(1)

SQL> BEGIN

2 DECLARE

3 expa EXCEPTION;

4 BEGIN

5 RAISE expa;

6 EXCEPTION

7 WHEN expa THEN

8 INSERT INTO t VALUES(12);

9 WHEN OTHERS THEN

10 dbms_output.put_line('內層捕捉到異常');

11 END;

12 EXCEPTION

13 WHEN OTHERS THEN

14 dbms_output.put_line('外層捕捉到異常');

15 END;

16 /

外層捕捉到異常

PL/SQL procedure successfully completed

SQL>

2007-5-7 19:10:25 一、在plsql中，oracle自帶的Exceptions如下：

Exception Oracle Error SQLCODE Value

ACCESS_INTO_NULL ORA-06530 -6530

CASE_NOT_FOUND ORA-06592 -6592

COLLECTION_IS_NULL ORA-06531 -6531

CURSOR_ALREADY_OPEN ORA-06511 -6511

DUP_VAL_ON_INDEX ORA-00001 -1

INVALID_CURSOR ORA-01001 -1001

INVALID_NUMBER ORA-01722 -1722

LOGIN_DENIED ORA-01017 -1017

NO_DATA_FOUND ORA-01403 +100

NOT_LOGGED_ON ORA-01012 -1012

PROGRAM_ERROR ORA-06501 -6501

ROWTYPE_MISMATCH ORA-06504 -6504

SELF_IS_NULL ORA-30625 -30625

STORAGE_ERROR ORA-06500 -6500

SUBSCRIPT_BEYOND_COUNT ORA-06533 -6533

SUBSCRIPT_OUTSIDE_LIMIT ORA-06532 -6532

SYS_INVALID_ROWID ORA-01410 -1410

TIMEOUT_ON_RESOURCE ORA-00051 -51

TOO_MANY_ROWS ORA-01422 -1422

VALUE_ERROR ORA-06502 -6502

ZERO_DIVIDE ORA-01476 -1476

2007-5-7 21:45:42 Oracle SQLCODE/SQLERRM

Oracle內置函數SQLCODE和SQLERRM是特別用在OTHERS處理器中，分別用來返回Oracle的錯誤代碼和錯誤消息。

OTHERS處理器應該是異常處理塊中的最后的異常處理器，因為它是用來捕獲除了別的異常處理器處理以外的所有的Oracle異常，所以在程序的最外層使用一個OTHERS處理器的話，將可以確保所有的錯誤都會被檢測到。

在一個內在的異常中，SQLCODE返回Oracle錯誤的序號，而SQLERRM返回的是相應的錯誤消息，錯誤消息首先顯示的是錯誤代碼。SQLCODE返回的是負數，除非Oracle的錯誤為“ORA-01403：NO DATA FOUND”（譯：ORA-01403：未找到數據），當Oracle錯誤為“ORA-01403：NO DATA FOUND”時，其對應的SQLCODE為+100。對于用戶自定義的異常，SQLCODE返回的是+1，而SQLERRM返回的是User-Defined Exception。

一個Oracle的錯誤消息最多只能包含512個字節的錯誤代碼。如果沒有異常被觸發，則SQLCODE返回0，SQLERRM返回“ORA-0000：normal, successful completion”。